SPARQL queries

Find typifications where there are multiple holotypes for the same name.

The following query uses these:

• Items: typification assertion (Q47338), Holotype (Q47316)

• Properties: instance of (P1), type status (P30), taxon name (P29)

  PREFIX tre: <https://tre-test.wikibase.cloud/entity/>
  PREFIX tred: <https://tre-test.wikibase.cloud/prop/direct/>
  
  SELECT ?item1Label ?item2Label ?item1 ?item2
  WHERE {
   ?item1 tred:P1 tre:Q47338;
      	tred:P30 tre:Q47316;
      	tred:P29 ?linkedItem .
   ?item2 tred:P1 tre:Q47338;
      	tred:P30 tre:Q47316;
      	tred:P29 ?linkedItem .
   FILTER (STR(?item1) < STR(?item2))
   SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  }
  

Try it!

E.g. https://tre-test.wikibase.cloud/wiki/Item:Q63097 and https://tre-test.wikibase.cloud/wiki/Item:Q63086 (likely duplicates in gbif, so the same specimen)

Find typifications of specimen with name item Q95004.

The following query uses these:

• Items: typification assertion (Q47338), Oxalis humbertii Lourteig (Q95004)

• Properties: instance of (P1), taxon name (P29)

  PREFIX tre: <https://tre-test.wikibase.cloud/entity/>
  PREFIX tred: <https://tre-test.wikibase.cloud/prop/direct/>
  
  SELECT ?typification ?typificationLabel WHERE {
    ?typification tred:P1 tre:Q47338;
              	tred:P29 tre:Q95004.
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  }
  

Try it!

Find typifications of Oxalis humbertii Lourteig

The following query uses these:

• Items: typification assertion (Q47338)

• Properties: instance of (P1), taxon name (P29), scientific name (P14)

  PREFIX tre: <https://tre-test.wikibase.cloud/entity/>
  PREFIX tred: <https://tre-test.wikibase.cloud/prop/direct/>
  
  SELECT ?item ?itemLabel
  WHERE {
    ?item tred:P1 tre:Q47338 ;
      	tred:P29 ?name .
    ?name tred:P14 "Oxalis humbertii Lourteig" .
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  }
  

Try it!

Find specimens which are types for the same name, but were collected more than a decade apart.

The following query uses these:

• Items: specimen (Q4)

• Properties: instance of (P1), taxon name (P29), event date (P39)

  PREFIX tre: <https://tre-test.wikibase.cloud/entity/>
  PREFIX tred: <https://tre-test.wikibase.cloud/prop/direct/>
  
  SELECT ?item1 ?item2
  WHERE {
    ?item1 tred:P1 tre:Q4;
       	tred:P29 ?linkedItem;
       	tred:P39 ?date1 .
    ?item2 tred:P1 tre:Q4;
       	tred:P29 ?linkedItem;
       	tred:P39 ?date2 .
    FILTER (STR(?item1) < STR(?item2))
    BIND(year(?date1) AS ?year1)
    BIND(year(?date2) AS ?year2)
    FILTER (abs(?year1 - ?year2) > 10)
  }
  

Try it!

List the number of typifications per typeStatus.

The following query uses these:

• Items: typification assertion (Q47338)

• Properties: instance of (P1), type status (P30)

  PREFIX tre: <https://tre-test.wikibase.cloud/entity/>
  PREFIX tred: <https://tre-test.wikibase.cloud/prop/direct/>
  
  SELECT ?linkedItem (COUNT(?typification) AS ?count) WHERE {
    ?typification tred:P1 tre:Q47338.  # P1 = instance of; Q47338 = typification assertion
    ?typification tred:P30 ?linkedItem.
  }
  GROUP BY ?linkedItem
  ORDER BY DESC(?count)
  

Try it!

Item classes and their counts

List of classes that are used as "instance of" (P1) and the count of items that are instances of them.

The following query uses these:

• Properties: instance of (P1)

  PREFIX tre: <https://tre-test.wikibase.cloud/entity/>
  PREFIX tred: <https://tre-test.wikibase.cloud/prop/direct/>
  SELECT ?class ?classLabel ?count{
    {
      SELECT ?class (COUNT(?instance) AS ?count) WHERE {
        ?instance tred:P1 ?class. 
      }GROUP BY ?class
    }
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }   
  }
  ORDER BY DESC(?count)
  

Try it!